Discussion :

[titi0685]

Bonjour,

J'ai besoin d'aide concernant la création d'onglet en vba. J'explique je récupère un export qui contient des lignes de production différentes 6C, 6D, ...

Je souhaite ,par le biais d'une variable nommée UP, créer à chaque changement d'UP (6C, 6D, ...) un onglet y coller toutes les lignes et nommer l'onglet de cet UP.

Voici ma macro qui ne fonctionne pas :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub CREERONGLET()
 
 ‘CREERONGLET Macro
 ‘Macro enregistrée le 17/09/2010 par Interforum
 
Dim UP As String
 
For i = 2 To 300
 
 
 If Range("A" & i).Value = "" Then
 Range("W" & i).Select
If ActiveCell.Value = "6C" Then
 SOURCE = Range("C" & i).Value
 On Error Resume Next
 Sheets("SOURCE").Select
Sheets("SOURCE").Copy after:=Sheets(2)
Sheets("SOURCE").Range("AE" & i).Value = "X"
‘toutes les op de collage et de mise en forme
If Range("A" & i).Value = "6D" Then
Sheets.Add.Name = UP
Sheets("SOURCE").Select
Sheets("SOURCE").Copy after:=Sheets(2)
Active Sheet.Name = "6D"
On Error Resume Next
End If
End If
End Sub

merci d'avance...

[PPz78]

Bonsoir,

Dans le mode Debug tu peux voir ce qui se passe mal et nous l'expliquer ensuite.
Bonne soirée.

PPz

[mercatog]

Si dans la feuille SOURCE on a nos données brutes.
En colonne A les codes des différentes lignes de production (tri non nécessaire)
Le code proposé ci après, parcours la colonne A et récupère les différents codes sans doublons (lignes de production)
Pour chaque code récupéré, on cherche l'existence de la feuille ayant comme nom ce code. Si elle existe, on la supprime.
On crée une nouvelle feuille, on la renomme par ce code
On filtre la feuille SOURCE par rapport à ce code en colonne A
On copie les lignes filtrées dans la nouvelle feuille créée
et on boucle sur tous les éléments de notre collection de code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Dim Lastlig As Long, i As Long
Dim Kol As New Collection
Dim Sh As Worksheet
 
Application.ScreenUpdating = False
With Sheets("SOURCE")                                   'Adapter le nom de la feuille
    .AutoFilterMode = False                             'Supprime le filtre auto
    Lastlig = .Cells(Rows.Count, "A").End(xlUp).Row     'Ligne de la dernière cellule remplie de la colonne A
    For i = 2 To Lastlig
        On Error Resume Next
        Kol.Add .Range("A" & i), .Range("A" & i)        'On parcours les cellules de la colonne A et en remplit dans Kol les codes sans doublons
        On Error GoTo 0
    Next i
    For i = 1 To Kol.Count                              'On boucle sur tous les codes (lignes de productions)
        '-----------------------------------------------------------------------
        On Error Resume Next
        Set Sh = Sheets(CStr(Kol(i)))
        On Error GoTo 0                                 'On cherche si la feuille existe déjà
        If Not Sh Is Nothing Then
            Application.DisplayAlerts = False           'Si oui, on la supprime
            Sh.Delete
            Application.DisplayAlerts = True
        End If
        '------------------------------------------------------------------------
        Set Sh = Sheets.Add(after:=Sheets(Sheets.Count))                        'On ajoute une nouvelle feuille
        Sh.Name = Kol(i)                                                        'On la renomme par le code
        '------------------------------------------------------------------------
        .Range("A1").AutoFilter Field:=1, Criteria1:=Kol(i)                     'On filtre sur le code
        .Range("A1:A" & Lastlig).SpecialCells(xlCellTypeVisible).EntireRow.Copy Sh.Range("A1") 'On copie toutes les lignes dans la feuille créée
        Set Sh = Nothing
    Next i
    .AutoFilterMode = False                                                     'Supprime le filtre auto
End With