Discussion :

[alexandreS]

Bonjour à tous,
J'espère que ce topic est toujours d'actualité

Je viens de commencer un stage, et la première mission qui m'a été donnée est de faire un listing des archives de l'entreprise depuis une dizaine d'années. Après une longue recherche, je suis enfin parvenu à trouver ce que je cherchais (enfin presque). Dans mon entreprise, les données sont stockées sur des DVD, qui contiennent plus de 4000 fichiers chacun. Je vous laisse imaginer la taille du fichier Excel quand j'utilise vos macros
Ce que je cherche à obtenir est la liste, non pas des fichiers, mais des dossiers. De plus, je souhaite limiter le "bouclage" pour les 5 premiers fichiers.
La macro de zyhack est celle qui ce rapproche le plus de ma demande mais je n'arrive pas à apporter les modifications nécessaires pour arriver à mes fins..

Quelles seraient les modifications que vous feriez sur la macro, dans l'unique but de me sauver la vie

Merci d'avance

[PPz78]

Bonsoir,

C'est difficile de t'aider sans plus de renseignements de ta part.
As tu essayé la fonction Dir, qui permet d'avoir le contenu d'un répertoire ?

PPz

[SilkyRoad]

Bonjour,

Tu peux adapter cet exemple qui liste les répertoires et les sous répertoires d'un dossier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
Option Explicit
 
Dim i As Integer
Dim Cible As Byte
 
 
Sub listeDossiersEtSousDossiers()
    Dim Racine As String
 
    Application.ScreenUpdating = False
 
    Racine = "C:\Documents and Settings\mimi\dossier"
    Cible = nbSeparateur(Racine)
    ListeReps Racine, True
 
    Application.ScreenUpdating = True
    i = 0
End Sub
 
 
Sub ListeReps(strDossier As String, strSousDossier As Boolean)
    ' adapté de Ole P Erlandsen
    Dim Fso As Object, SourceFolder As Object
    Dim SubFolder As Object
 
    On Error GoTo Fin
 
    Set Fso = CreateObject("Scripting.FileSystemObject")
    Set SourceFolder = Fso.GetFolder(strDossier)
 
    If strSousDossier Then
        For Each SubFolder In SourceFolder.subfolders
            i = i + 1
            'pour recuperer le chemin complet
            'Cells(i, nbSeparateur(SubFolder.Path) - Cible) = SubFolder.Path
            '
            'pour recuperer uniquement le nom du dossier
            Cells(i, nbSeparateur(SubFolder.Path) - Cible) = SubFolder.Name
 
            ListeReps SubFolder.Path, strSousDossier
        Next SubFolder
    End If
 
Fin:
End Sub
 
 
Function nbSeparateur(Chemin As String) As Byte
    Dim m As Integer
    Dim Nb As Byte
 
    For m = 1 To Len(Chemin)
        If Mid(Chemin, m, 1) = "\" Then
            Nb = Nb + 1
            m = m + 1
        End If
    Next m
    nbSeparateur = Nb
End Function

bonne journée
michel

[PPz78]

Bonjour,

On ne le dit pas assez souvent, VBA est capable de récursivité et la solution de SilkyRoad utilise cette capacité. BRAVO

PPz