Discussion :

[debdev]

Bonjour,

J’ai un souci avec le call execute.
J’ai une table à 20 lignes et une colonne.
J’ai stocké mes 20 valeurs dans des macro variables.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
data table;
	set table;
	call symputx(cats("a",_n_), cod);
run;

Je souhaite exécuter ma macro (qui fonctionne) pour chacune de mes macrovariables, que je passe en paramètre.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
data _null_;
	set table;
    	do i = 1 to nbcod;
		call execute('%mamacro(tablein1,tablein2,grp,petit,&&a&i,&i)');
	end;
run;

Questions :

1. combien de fois call execute est elle lancée ?
- nbcod fois correspondant à mon i ?
- nbcod fois correspondant au nombre de ligne dans table ?
- nbcod*nbcod fois car à chaque itération du data step (total=nbcod fois), call execute est lancée nbcod fois ?

2.
sans la boucle, sans le call execute : ma macro se lance comme il faut
sans la boucle, avec le call execute : ma macro se lance comme il faut
avec la boucle, avec le call execute : ma macro ne se lance pas comme il faut
=> je n’arrive pas à passer le paramètre i : si je mets &i, il n’est pas reconnu
WARNING: Apparent symbolic reference I not resolved.
ERROR: The text expression &I contains a recursive reference to the macro variable I. The macro variable will be assigned the null value.


Auriez vous une idée ?

Merci

[sasadm]

Salut,

Un des intérêts du call execute est de fournir une alternative au code macro pour "produire" du code à la chaine.


Voilà un exemple d'utilisation :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
 
 
data TABLE2;
input cod $;
cards;
cod1
cod2
cod3
;
run;
 
%macro mamacro2(data1, data2, _grp, _petit, _cod, _n) ;
	%put data1=&data1. data2=&data2. _petit=&_petit. ;
 
	data _null_;
	cod="&_cod" ; n="&_n";
	put cod= n=;
	run;	
%mend;
 
 
DATA _null_;
SET TABLE2;
call execute('%mamacro2(tablein1, tablein2, grp, petit, '||cod||', '||_n_||' )');
run;

En fait call execute permet d'exécuter un programme contenu dans une "chaine de caractere".

J'aurais pu écrire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
 
DATA _null_;
SET TABLE2;
length pgm $128;
pgm=cats('%mamacro2(tablein1, tablein2, grp, petit, ', cod, ', ', _n_, ' )');
call execute(pgm);
run;

Par ailleurs, fais bien la distinction entre variable sas et macro variable.

Quand tu écris do i=1 to 5, une variable sas i va prendre successivement les valeurs 1,2,3,4,5. Ce n'est pas une macro variable.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
 
data _null_;
 
put "debut boucle";
do i=1 to 5 ;
 u=i;/* et non &i */
 put u=; 
end;
put "fin boucle";
 
run;

[debdev]

Bonjour,

Un GRAND MERCI à toi saspgm
Je n'aurai jamais trouvé sans toi. J'étais partie dans des call symput pour mémoriser les valeurs de ma variable, boucler sur le dataset...

Et merci pour tes explications



bonne journée