Bonsoir,
Essaie avec ce code
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36
| Sub OuvrirClasseurExcelApercu(strClasseur As String)
Dim appExcel As Excel.Application 'Application Excel
Dim wbExcel As Excel.Workbook 'Classeur Excel
Dim blnExcelCreated As Boolean
' Ouverture de l'application
On Error Resume Next
Set appExcel = GetObject(, "Excel.Application")
On Error GoTo 0
If appExcel Is Nothing Then
' Excel n'est pas ouvert (aucune instance)
' On crée une instance d'Excel
Set appExcel = CreateObject("Excel.Application")
appExcel.Visible = True
blnExcelCreated = True
Else
blnExcelCreated = False
End If
' Ouverture du fichier Excel en lecture seule
Set wbExcel = appExcel.Workbooks.Open(strClasseur, , True)
' Active l'application Excel pour l'afficher au premier plan
AppActivate appExcel.Caption
' Aperçu avant Impression
wbExcel.PrintPreview
' Ferme le classeur Excel
wbExcel.Close False
Set wbExcel = Nothing
' Ferme l'appli Excel si l'instance a été créée par ce code
If blnExcelCreated Then
appExcel.Quit
End If
Set appExcel = Nothing
End Sub |
Exemple :
OuvrirClasseurExcelApercu "E:\Mes Documents\Excel\mon fichier.xls"
A+
Partager