Discussion :

[Merryvor]

Bonjour,

Suite à une harmonisation des feuilles d'ordre de travail, on me demande d'abandonner mon état access, et d'exporter les données vers une feuille excel, abordable par tous.

J'ai bien réussi l'exportation. Mon problème vient de l'aspect rébarbatif.
(Avant au clic du bouton, paf l'état arrive en mode aperçu, clic droit sur menu contextuel personalisé, paf fenêtre d'impression, je ferme l'état pas de demande de svgde).

Maintenant tout ceci prend plus de clic.
Dans mon code j'ai mis:

Code vba :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
xlApp.Visible=True
xlSheet.PrintPreview = True

Mais ca ne fonctionne pas. IL affiche l'aperçu, mais aussi
"erreur d'exécution 1004: impossible de définir la propriété PrintView de la classe Worksheet"

Comment ouvrir en aperçu, puis obliger le document à se fermer sans sauvegarde?

[LedZeppII]

Bonsoir,

Essaie avec ce code

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub OuvrirClasseurExcelApercu(strClasseur As String)
Dim appExcel As Excel.Application 'Application Excel
Dim wbExcel As Excel.Workbook     'Classeur Excel
Dim blnExcelCreated As Boolean
 
' Ouverture de l'application
On Error Resume Next
Set appExcel = GetObject(, "Excel.Application")
On Error GoTo 0
If appExcel Is Nothing Then
   ' Excel n'est pas ouvert (aucune instance)
   ' On crée une instance d'Excel
   Set appExcel = CreateObject("Excel.Application")
   appExcel.Visible = True
   blnExcelCreated = True
Else
   blnExcelCreated = False
End If
 
' Ouverture du fichier Excel en lecture seule
Set wbExcel = appExcel.Workbooks.Open(strClasseur, , True)
' Active l'application Excel pour l'afficher au premier plan
AppActivate appExcel.Caption
' Aperçu avant Impression
wbExcel.PrintPreview
 
' Ferme le classeur Excel
wbExcel.Close False
Set wbExcel = Nothing
 
' Ferme l'appli Excel si l'instance a été créée par ce code
If blnExcelCreated Then
   appExcel.Quit
End If
Set appExcel = Nothing
End Sub

Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

OuvrirClasseurExcelApercu "E:\Mes Documents\Excel\mon fichier.xls"

A+