Discussion :

[Danieldu54]

Bonsoir,

j'ai déjà écumer un peu tous les forums, sans vraiment trouver les réponses à mon problème, donc je viens vous l'exposer:

J'ai un fichier source dans un repertoire connu et fixe : C:\users\public\Fichier_source.xls
J'ai un second fichier dans un répertoire inconnu que je doit remplacer par le fichier_source.xls mais avec son nom d'origine exemple xxx25846_fiche.xls.

Je cherche un code afin qu'au lancement de ma macro, on me demande ou est le fichier à remplacer, puis remplace le fichier.

Le top serait qu'après avoir effectuer ce remplacement, qu'il me demande par une msgbox si je veux ouvrir le fichier fraichement remplacé 'oui ou non'. Si non il ferme excel si oui il l'ouvre.

Je précise que le remplacement de fichier doit être fait sans les ouvrir car ils ont des macros auto_open. J'ai trouver ça : mais ne s'applique pas dans mon cas car le répertoire du second fichier m'est inconnu et est variable :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

oFSO.CopyFile("C:\users\public\Fichier_source.xls","I:\temp\xxx25846_fiche.xls",True)

Avez-vous des propositions ?

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub RenommeFichier()
Dim fichSource As String, cheminDest As String, nomSource As String, nomDest
Dim fichDest As Variant
Dim objOFS As Variant
 
fichSource = "C:\users\public\Fichier_source.xls"
nomSource = Mid(fichSource, InStrRev(fichSource, "\") + 1)
Set objOFS = CreateObject("Scripting.FileSystemObject")
If objOFS.FileExists(fichSource) Then
    fichDest = Application.GetOpenFilename("Excel Files (*.xls), *.xls")
    If fichDest <> False Then
        cheminDest = Left(fichDest, InStrRev(fichDest, "\"))
        objOFS.moveFile fichSource, cheminDest
        Kill fichDest
        Name cheminDest & nomSource As fichDest
        If MsgBox("Voulez ouvrir le fichier qui vient d'être déplacé et renommé?", vbOKCancel) = vbOK Then Workbooks.Open fichDest
    End If
End If
Set objOFS = Nothing
End Sub

Ou aussi simplement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub renomme()
Dim fichSource As String
Dim fichDest As Variant
 
fichSource = "C:\users\public\Fichier_source.xls"
fichDest = Application.GetOpenFilename("Excel Files (*.xls), *.xls")
If fichDest <> False Then
    Kill fichDest
    Name fichSource As fichDest
    If MsgBox("Voulez ouvrir le fichier qui vient d'être déplacé et renommé?", vbOKCancel) = vbOK Then Workbooks.Open fichDest
End If
End Sub

[Danieldu54]

Unpeccable ! J'ai tester la solution 2 (plus simple) ça fonctionne correctement sauf qu'il me supprime le fichier source

Une petit plus-value si c'est pas trop compliquer à faire :

prédéfinir un dossier dans lequel la boite doit s'ouvrir (un chemin par défaut en dur dans le code suffit) est-ce possible ?

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub RenommeFichier()
Dim fichSource As String, cheminDest As String, nomSource As String, nomDest
Dim fichDest As Variant
Dim objOFS As Variant
 
fichSource = "C:\Documents and Settings\Administrateur\Bureau\DATA\B_CSF\ActCtrl06-07.xls"
nomSource = Mid(fichSource, InStrRev(fichSource, "\") + 1)
cheminDest = "C:\Documents and Settings\Administrateur\Bureau"
ChDir cheminDest
Set objOFS = CreateObject("Scripting.FileSystemObject")
If objOFS.FileExists(fichSource) Then
    fichDest = Application.GetOpenFilename("Excel Files (*.xls), *.xls")
    If fichDest <> False Then
        cheminDest = Left(fichDest, InStrRev(fichDest, "\"))
        objOFS.copyfile fichSource, cheminDest
        Kill fichDest
        Name cheminDest & nomSource As fichDest
        If MsgBox("Voulez ouvrir le fichier qui vient d'être déplacé et renommé?", vbYesNo) = vbYes Then Workbooks.Open fichDest
    End If
End If
Set objOFS = Nothing
End Sub

[Danieldu54]

C'est bon pour le fichier source, il ne le supprime plus

Merci beaucoup !

[Danieldu54]

Bonsoir,

Je reviens sur le message, car il reste une chose qui ne fonctionne pas :

Après s'être exécuter normalement, le code demande si je veux lancer le nouveau fichier ainsi obtenu. Si je valide, il m'ouvre correctement le fichier, sauf que celui-ci contient une macro auto_open qui refuse de s'ouvrir automatiquement.

Elle se lance que si je le fais manuellement. J'ai essayé de l'intégrer dans le code mais je reviens à mon problème de nom de fichier variable:

Le nouveau code serai :

application.run "NOM DU FICHIER"!auto_open
Mais avec NOM DU FICHIER renseigné automatiquement ...

[Vadorblanc]

Bonsoir
J'avais le même problême sur un changement de nom du fichier avec la macro qui cherchait le même nom du fichier:Application.Run"Nom du fichier" que j'ai changé par 'Call' 'nom de la macro' et tout était ok ensuite.
La ligne de code 'Application.Run' est une ligne de code généré par l'éditeur de macro Excel qu'il faut changer impérativement par la commande 'Call'
Cordialement

[AlainTech]

Ce serait moi, je remplacerais la macro Auto_Open (obsolète) par l'événement Open de l'objet ThisWorkbook.